Fixing dillo.

teckk · 02-01-2022, 10:56 AM

I'll post this in the arch forum because, that's where I built it. Anyone else should be able to compile it too. You need dillo's 3.1 devel source, it's depends and mbedtls. Your distro might name that slightly different. Someone else mentioned this in another thread about small light browsers on the Slack forum. So I decides to investigate it.

Anyone who is interested.

As you know dillo hasn't worked right for years. This fixes it so that it loads pages like it should. There isn't an AUR package for it. I haven't seen a post on it.

Get 3.1 dev source here.
https://github.com/orsenthil/dillo
https://github.com/orsenthil/dillo/a...ads/master.zip

Install mbedtls

Code:

pacman -S mbedtls

I made a PKGBUILD for it. (Build from a local source tree after you have it).

PKGBUILD

Code:

#Local PKGBUILD example

pkgname=dillo3dev
pkgver=3.1.dev
pkgrel=8
pkgdesc="A small, fast graphical web browser built on FLTK"
arch=(x86_64)
license=('GPL')
depends=('fltk' 'libjpeg' 'perl' 'libpng' 'gcc-libs' 'libxcursor'
         'libxi' 'libxinerama')
backup=(etc/dillo/{dillorc,dpidrc})

build() {
  cd "/path/to/the/source/dillo-master"
  CFLAGS+=' -fcommon'
  ./configure --prefix=/usr --sysconfdir=/etc --enable-cookies --enable-ssl
  make
}

package() {
  cd "/path/to/the/source/dillo-master"
  make DESTDIR="$pkgdir" install

  install -Dm644 ../dillo.desktop "$pkgdir/usr/share/applications/dillo.desktop"
  install -Dm644 ../ProgramIcon48.png "$pkgdir/usr/share/pixmaps/dillo.png"
}

dillo.desktop

Code:

[Desktop Entry]
Name=Dillo
GenericName=Web Browser
Comment=Very small and fast GUI web browser
Exec=dillo
Icon=dillo
Terminal=false
Type=Application
Categories=Network;GTK;WebBrowser;

ProgramIcon48.png

Code:

curl -F'file=@ProgramIcon48.png' https://0x0.st
https://0x0.st/oHyw.png

And that builds fine and runs.

I already have dillo installed so I never bothered to install this fixed version. I simply ran it from the build directory. I wanted to see if this would fix it. Point is, it has loaded all the pages that I have thrown at it, including cloudflare sites.

Code:

curl -F'file=@dilLQ.png' https://0x0.st
https://0x0.st/oHy3.png

If no one is interested in dillo, that's fine. It used to be one of my favorite browsers when it worked 5 or 6 years ago.

And if anyone is interested in making that little obnoxious scroll bar thicker so that you can actually grab it.

That is at:
/dillo-master/dw/fltkviewport.hh
Line 20

Code:

class FltkViewport: public FltkWidgetView
{
public:
   enum GadgetOrientation { GADGET_VERTICAL, GADGET_HORIZONTAL };

private:
   enum { SCROLLBAR_THICKNESS = 15 };

   int scrollX, scrollY;
   int scrollDX, scrollDY;
   int hasDragScroll, dragScrolling, dragX, dragY;
   int horScrolling, verScrolling;

Ok, my 2 cents worth.

shruggy · 02-01-2022, 11:14 AM

Here is my RPM spec file for Dillo.

ondoho · 02-01-2022, 11:31 AM

This just builds the git master without any changes, yes?
build() and package() seem to be the same as for the community package, the prepare() function presumably isn't necessary anymore?

shruggy · 02-01-2022, 12:01 PM

Quote:

Originally Posted by ondoho

the prepare() function presumably isn't necessary anymore?

Yep. It's not needed. From my changelog:

Code:

- Latest snapshot
- Disable LTO
- Drop BR on gtk+-devel
- Replace BR on openssl-devel with mbedtls-devel
- Drop patch for OpenSSL 1.1.1
- Patch test/Makefile.am to link dw_simple_container_test with -lX11
- Add icons

teckk · 02-01-2022, 12:19 PM

Thanks @ondoho, I don't think that I even knew about that. Learn something new all of the time.

openssl patch
https://github.com/archlinux/svntogi.../openssl.patch

So no, the build I did does not use openssl. It uses mbedtls.

Code:

pacman -Si mbedtls
...
Provides        : polarssl  libmbedcrypto.so=7-64  libmbedtls.so=13-64
                  libmbedx509.so=1-64

I also failed to retrace my steps well enough. From that source above one needs to run autogen.sh manaully first to make a configure file, or make it part of the PKGBUILD.

My goal was so that everyone, whatever distro they used, could easily get the source and compile it, if they wanted to.

ondoho · 02-02-2022, 02:34 AM

^ So the current git master of dillo depends on mbedtls instead of openssl?
It's not in the depends array of your PKGBUILD.

Dunno, I might make a proper dillo-git package from this, it's currently not in the AUR.

teckk · 02-02-2022, 08:02 AM

I just built this fresh from an empty directory to make sure it builds from this PKGBUILD

Here is a new PKGBUILD.

Code:

pkgname=dillo-master
pkgver="3.1.d"
pkgrel=10
pkgdesc="Dillo using mbedtls"
arch=(x86_64)
license=('GPL')
depends=('fltk' 'libjpeg' 'perl' 'libpng' 'gcc-libs' 'libxcursor'
         'libxi' 'libxinerama' 'mbedtls')
backup=(etc/dillo/{dillorc,dpidrc})

source=(https://github.com/orsenthil/dillo/archive/refs/heads/master.zip
        https://github.com/archlinux/svntogit-community/blob/packages/dillo/trunk/dillo.desktop
        https://www.dillo.org/Icons/ProgramIcon128.png)
        
sha256sums=('SKIP'
            'SKIP'
            'SKIP')

build() {
  cd "$srcdir/$pkgname"
  ./autogen.sh
  CFLAGS+=' -fcommon'
  ./configure --prefix=/usr --sysconfdir=/etc --enable-cookies --enable-ssl
  make
}

package() {
  cd "$srcdir/$pkgname"
  make DESTDIR="$pkgdir" install

  install -Dm644 ../dillo.desktop "$pkgdir/usr/share/applications/dillo.desktop"
  install -Dm644 ../ProgramIcon48.png "$pkgdir/usr/share/pixmaps/dillo.png"
}

And that built and run. Change that however you want.

And if you want to make a patch for the scrollbar size.
../src/dillo-master/dw/fltkviewport.hh
Line 20

I'm an amature with the AUR. Never posted anything in it. I've always built stuff from source for myself and used it. Plus, the devs are kinda harsh if you don't get it right. (Which is why I haven't posted anything in it.) Maybe I'll look into that one of these days when I have lots of time to get it right. You seen to know how to do it.

I don't think that there is that much interest in dillo. Just something that i have wanted to fix for 3 or 4 years now. Got around to it.

teckk · 02-02-2022, 08:10 AM

And that seems to open everything that you throw at it.

Code:

curl -F'file=@dil2.png' https://0x0.st
https://0x0.st/oHgz.png

https://0x0.st/oHgz.png

boughtonp · 02-02-2022, 08:30 AM

It seems Dillo uses it's own rendering engine (not webkit/gecko/etc), which has me curious, but I've yet to find anything on Dillo or FLTK websites - don't suppose anyone knows where there's details?

teckk · 02-02-2022, 09:07 AM

What are you referring to? It's own web browser engine?

You'll have to look at it's source code. It is part of it. It is not a seperate engine like webkit, webengine, blink etc. It is in the source, I can't tell you a lot more. I'm not an expert on it. I looked the code base over to change it the way I wanted. I think that you probably would have to talk to the dillo devs to fully understand it. That's quite a bit of code there, just like a lot of projects. There are some readme's in the source tree.

It doesn't run scripts, doesn't even display frames correctly. fltk of course is just the tool kit for the graphics. It is a very fast little browser that just diplays the essence of the page. You can post on LQ wit hit, I've done it before just not as convenient. And...It wont keep the formatting that you use sometimes.

Something else that it will do. Most web browsers, if you turn javascript and images off. If you load some pages you get a blank page. Dillo will diplay the page. It simply does not redirect to the "Blank page" because you don't have scripts on.

teckk · 02-02-2022, 09:12 AM

From the source tree there is...
https://github.com/orsenthil/dillo/tree/master/devdoc
https://github.com/orsenthil/dillo/tree/master/devdoc

boughtonp · 02-02-2022, 10:12 AM

Yeah, I just want something simple to look at - I suspect Dillo will be easier to comprehend than Firefox/etc, and it certainly wont waste disk space - its under 100MB vs "at least 30GB" (!) for FF...

ondoho · 02-03-2022, 02:35 AM

teckk, how did you arrive at that dependency list? Compare to the community version. Is there a reason why you dropped zlib?

Anyhow, I had to fix a few things:

renamed to dillo-git to conform with AUR practices
you had the wrong link for the .desktop file
"conflicts" is required otherwise pacman goes haywire over an already installed version of dillo
tried to fix versioning (I'm not good at this either) for git packages

These things I'm sure about, the dependencies not so much. I just took what was in the [community] version and replaced openssl with mbedtls.

So, new PKGBUILD:

Code:

# teckk & ondoho 2022
pkgname=dillo-git
pkgver=20181013081556
pkgrel=2
epoch=1
pkgdesc="Dillo using mbedtls"
provides=(dillo)
conflicts=(dillo)
arch=(x86_64)
license=('GPL')
depends=('fltk' 'libjpeg' 'libpng' 'mbedtls' 'perl' 'zlib' )
backup=(etc/dillo/{dillorc,dpidrc})
url="https://github.com/orsenthil/dillo"
source=("$pkgname::git+${url}.git"
        https://raw.githubusercontent.com/archlinux/svntogit-community/packages/dillo/trunk/dillo.desktop
        https://www.dillo.org/Icons/ProgramIcon128.png)
sha256sums=('SKIP'
            'e94ead3a359c2eceb934b07af0fac4864251b9721fa7f4855331daa017b66202'
            '72ecb57983117b17f0777caf6cf935a2ad5d72aca7b07b11f5b75562cb420778')

pkgver() {
    cd "${srcdir}/${pkgname}"
    git log -1 --format="%cd" --date="format:%Y%m%d%H%M%S"
}

build() {
  cd "$srcdir/$pkgname"
  ./autogen.sh
  CFLAGS+=' -fcommon'
  ./configure --prefix=/usr --sysconfdir=/etc --enable-cookies --enable-ssl
  make
}

package() {
  cd "$srcdir/$pkgname"
  make DESTDIR="$pkgdir" install

  install -Dm644 ../dillo.desktop "$pkgdir/usr/share/applications/dillo.desktop"
  install -Dm644 ../ProgramIcon128.png "$pkgdir/usr/share/pixmaps/dillo.png"
}

___________________

Quote:

Originally Posted by boughtonp

It seems Dillo uses it's own rendering engine (not webkit/gecko/etc), which has me curious, but I've yet to find anything on Dillo or FLTK websites - don't suppose anyone knows where there's details?

dillo is just a very small, very fast GUI browser. I use it for some hotkeys (e.g. to show me the online conky documentation) and never to actually browse. It's functional, but doesn't do javascript. Think Internet Explorer 5.
FLTK (the fast light toolkit) is used in a few other applications.
Both it and dillo have their own websites.

teckk · 02-03-2022, 07:42 AM

Code:

makepkg
==> ERROR: Missing package() function in ~/test/dillo5/PKGBUILD

Added:

Code:

package() {
  cd "$srcdir/$pkgname"
  make DESTDIR="$pkgdir" install

  install -Dm644 ../dillo.desktop "$pkgdir/usr/share/applications/dillo.desktop"
  install -Dm644 ../ProgramIcon128.png "$pkgdir/usr/share/pixmaps/dillo.png"
}

And that built fine without modifying any of the source. I didn't install it. The executable is at:
<BuidDir>/src/dillo-git/src/dillo

And that appears to load everything thrown at it. Here is a collage of screen grabs. The text looks better than that. I did a lesser quality jpeg for size sake.

Warning, image is still 2.6 MB. (Fairly big for a jpeg)

Code:

curl -F'file=@diltest.jpg' https://0x0.st
https://0x0.st/oHGj.jpg

https://0x0.st/oHGj.jpg

And sure enough, someone is going to ask me how I made that collage.
In my ~/.fluxbox/keys I have the Prt Scr key mapped to:

Code:

###PrtScr key 
#Capture desktop
Print :Exec scrot
#Print :Exec import -window root 0.png
#Print :Exec imlib2_grab 0.png
#Print :Exec ffmpeg -f x11grab -video_size 1920x1080 -i $DISPLAY -vframes 1 0.png
#Capture Focused window
Mod4 Print :Exec sleep 3 && scrot -u
#Mod4 Print :Exec scrot -u
#Mod4 Print :Exec import -screen 0.png
#Capture Select area
Control Print :Exec fbrun -text "scrot -s"
#Capture terminal session. exit to stop.
Mod1 Print :Exec xterm -e script

Then I used imagemagick. (Stripped down version)

Code:

#! /usr/bin/bash

echo "Montage images"
read -p $'\nEnter/Paste image files :' im_files
im_files=($im_files)

while :; do
    read -p $'\nNumber of tiles wide :' tiles
    read -p $'\nOutfile name :' out_file

    montage -mode concatenate \
    -title "XX Collage of dillo pages XX" \
    -tile "$tiles" "${im_files[@]}" "$out_file"

    file "$out_file"
    du -h "$out_file"

    read -p $'\nEnter resize for image(50% 20%) :' re_size

    convert "$out_file" -resize "$re_size" "$out_file"

    file "$out_file"
    du -h "$out_file"

    read -p $'\nFile size, image size right? Enter y or n :' yn
    case "$yn" in
        [Yy]* ) exit ;;
    
        [Nn]* ) echo -e "\nTry again then" ;;
    esac
done

teckk · 02-03-2022, 08:34 AM

And if you want to see that scrollbar fix. I Make it way too big to show it.

And for anyone not using arch that would like to compile it the old fashioned way.

<BuildDir>/src/dillo-git/dw/fltkviewport.hh

Code:

class FltkViewport: public FltkWidgetView
{
public:
   enum GadgetOrientation { GADGET_VERTICAL, GADGET_HORIZONTAL };

private:
   enum { SCROLLBAR_THICKNESS = 45 }; //Way too big

Code:

cd <BuildDir>/src/dillo-git
make clean
./autogen.sh
make

Then run
<BuildDir>/src/dillo-git/src/dillo

And the scrollbars will look like this silly example:
https://0x0.st/oHGG.png